Событие (объектно-ориентированное программирование)

Делегатно-событийная модель. clickme — источник события — кнопка содержит список наблюдателей (слушателей).

События позволяют классу или объекту уведомлять другие классы или объекты о возникновении каких-либо ситуаций. Класс, отправляющий (или вызывающий) событие, называется издателем, а классы, принимающие (или обрабатывающие) событие, называются подписчиками. События представляют собой экземпляры делегатов, способные хранить, добавлять и удалять делегаты такого же типа (обработчики событий). При вызове события вызываются все делегаты, которые были добавлены к событию. События могут быть вызваны только из класса или объекта, которому принадлежит событие.[3] Делегатно-событийная модель, применяемая, например, при разработке графических интерфейсов, основана на:

• управляющем объекте, который является источником событий
• наблюдателе, который также называется обработчиком событий, который получает уведомления о событиях от источника
• интерфейсах (в более широком смысле), которые описывают способ (протокол) обмена событиями.

К тому же, модель требует, чтобы:

• каждый наблюдатель реализовал интерфейс для событий, на которые он хочет подписаться
• каждый наблюдатель должен зарегистрироваться в источнике, чтобы выразить о намерении получать события.
• каждый раз, когда источник генерирует событие, он передаёт его наблюдателям по протоколу интерфейса.

В VB.NET события объявляются ключевым словом Event. Если опущен тип делегата, то компилятор сам создаст его, который может в дальнейшем содержать ссылку на метод, реализованный в подписчике.

Реализовать подписку на событие можно несколькими способами:

• evtSample As sampleDel — механизм регистрации обработчика события для данного типа декларации должен быть предоставлен классом с объявленным событием. Событие генерируется путём вызова метода в делегате evtSample.
• Public Event evtSample As sampleDel — обработчик событий может быть зарегистрирован с помощью оператора AddHandler, который свяжет событие источника и метод в классе подписчика. Событие реализуется с помощью объявленного делегата sampleDel. Событие генерируется используя оператор RaiseEvent.
• Public Event evtSample — обработчик события будет зарегистрирован с помощью ключевых слов WithEvents в объявлении экземпляра класса и Handles в самой декларации метода класса подписчика. Событие реализуется с помощью неявно объявленного делегата. Событие генерируется используя оператор RaiseEvent.

Imports System

Public Class CTimer

    Delegate Sub SecondDel(ByVal xintTime As Integer)
    Private evtSecond As SecondDel

    Public Event evtMinute As SecondDel
    Public Event evtHour(ByVal xHour As Integer)
    public Shared lngSeconds As Long
    
    Public Sub Register(ByVal objSecond As SecondDel)
        evtSecond = evtSecond.Combine(evtSecond, objSecond)
    End Sub
    
    Public Sub OnTimer()
        lngSeconds = lngSeconds + 1
        If lngSeconds Mod 5 = 0 Then
            evtSecond(lngSeconds) 'Вызов метода делегата
        End If
        If lngSeconds Mod 10 = 0 Then
            RaiseEvent evtMinute(lngSeconds) 'Генерация события
        End If
        If lngSeconds Mod 30 = 0 Then
            RaiseEvent evtHour(lngSeconds) 'Генерация события
        End If
    End Sub

End Class

Public Class CClock
    
    Private WithEvents mobjTimer As CTimer 'Объявление объекта класса, с возможностью подключения к событиям
    
    Sub New()
        mobjTimer = New CTimer()
        mobjTimer.Register(New CTimer.SecondDel(AddressOf SecondEvent)) 'Регистрация события через метод предоставленный классом
        AddHandler mobjTimer.evtMinute, AddressOf MinuteEvent 'Регистрация события с помощью оператора AddHandler
        While (mobjTimer.lngSeconds < 60)
            mobjTimer.OnTimer()
            System.Threading.Thread.Sleep(100)
        End While
    End Sub
    
    Private Sub SecondEvent(ByVal xintTime As Integer)
        Console.WriteLine("Second's Event")
    End Sub

    Private Sub MinuteEvent(ByVal xintTime As Integer)
        Console.WriteLine("Minute's Event")
    End Sub

    'Регистрация события с помощью ключевого слова Handles
    Private Sub mobjTimer_evtHour(ByVal xintTime As Integer) Handles mobjTimer.evtHour
        Console.WriteLine("Hour's Event")
    End Sub

    Public Shared Sub Main()
        Dim cc1 = New CClock()
    End Sub

End Class